Treeless Software VB example class is used to Print Multi Page Reports

Printing in a .Net (or any VB) program has always been a challenge. I developed the following VB.Net Class (with guidance from others) using Visual Studio 2010 to help simplify the printing process. This Class was developed to handle multi-page printed reports.

A Visual Studio 2010 project for DemoPrintHelperPages is available for your use.

Formatting and creating a multi-page printed report is done by a two step process.

First, create the PrintHelperPages Class and place the Class in "Layout Mode" by setting the LayoutMode property to True. Then create the report by using the Print Functions. This will create a list of phLayout structures that define where on each page your text will be printed. This first pass will detect when a line will exceed the allowable printable region for a page. If a line will exceed the printable region, a new page is forced and the line will be located at the top of the next page.
Next, turn off LayoutMode and call the Print Routines with the phLayout structures to print a specific page.

The class can be created with:

Dim php As New PrintHelperPages(_event, _font, _debug)

Parameter	Type	Description
_event	System.Drawing.Printing.PrintPageEventArgs	From the Event Handler
_font	Font	(optional) Default Font
_debug	Boolean	(optional) Debug Flag (draw boxes around text) - Default is False

Text can be Laid-Out or Printed by calling one of the following routines. These routines will return a formatted Print Helper Page Layout Structure:

Dim phl As phLayout = php.Print(_text, _UpdateX, _HeaderFooter, _AlignToX)
Dim phl As phLayout = php.Print(_text, _x, _y, _UpdateX, _HeaderFooter, _AlignToX)
Dim phl As phLayout = php.Print(_text, _fontIndex, _UpdateX, _HeaderFooter, _AlignToX)
Dim phl As phLayout = php.Print(_text, _fontIndex, _x, _y, _UpdateX, _HeaderFooter, _AlignToX)
Dim phl As phLayout = php.Print(_text, _fontIndex, _sfIndex, _UpdateX, _HeaderFooter, _AlignToX)
Dim phl As phLayout = php.Print(_text, _fontIndex, _sfIndex, _y, _UpdateX, _HeaderFooter, _AlignToX)

Dim phl As phLayout = php.Print(_text, _fontIndex, _sfIndex, _x, _y, _UpdateX, _HeaderFooter, _AlignToX)

Parameter	Type	Description
_text	String	String to print
_fontIndex	Integer	Index of Font in Font List to use for this string
_sfIndex	Integer	Index of StringFormat in StringFormat List to left/right/center justify the text
_x	Single	X or horizontal position on the page to begin printing
_y	Single	Y or vertical position on the page to begin printing
_UpdateX	Boolean	(optional) Update X Coordinate after Print - Default is False
_HeaderFooter	Boolean	(optional) Are we printing a Header or Footer outside usable range - Default is False
_AlignToX	Boolean	(optional) Alignment is based on X rather than margin width - Default is False

To add a formatted phLayout structure to the list, the following is an example:

php.LayoutMode = True
Dim phl As New List(Of PrintHelperPages.phLayout)
phl.Add(m_php.Print("First Line on the Report"))
phl.Add(m_php.Print("Second Line on the Report"))
php.LayoutMode = False
php.Print(phl, 1) ' Actually print page one

If no X position is given, the string will begin at the left margin unless _UpdateX option was used on a prior Print statement. The _UpdateX option will reset the default X position to the end of the current Text printed. Don't forget to reset the default X position by using the xPos property, usually setting it to e.MarginBounds.X.

If no Y position is given, the current vertical position will be used, which is updated after each line is printed.

A new feature has been added to allow the alignment to be based on the X position rather than the usable region width. For example, if AlignToX is set the False (default value) and you have a string format set to center, your text will be centered on the page. But, if you set AlignToX to True, then your text will be centered on your X coordinate.

Print Helper Page Layout Structure (phLayout):

Dim phl As New phLayout

Variable	Type	Description
Text	String	Text to Print
fIndex	Integer	Font List Index
sfIndex	Integer	StringFormat List Index
Page	Integer	Page Number of Text
x	Single	X Position to start
y	Single	Y Position to start
AlignToX	Boolean	Alignment is based on X rather than margin width

The following Routines can be called after your print pages have been Laid-Out to actually print your pages. You pass as a parameter either a single phLayout record or the entire list of phLayout structures to print a specific page.

php.Print(_phLayouts As List(Of phLayout), _page As Integer)

php.Print(_phl As phLayout)

Parameter	Type	Description
_phLayouts	List(Of phLayout)	List Array of formatted Print Helper Page Layout Structures
_page	Integer	Specific page to print
_phl	phLayout	Formatted Print Helper Page Layout Structure

Class Properties:

Property Name	Type	Description
Debug	Boolean	Get or Set the Debug Flag
LayoutMode	Boolean	Get or Set whether we are in Layout Mode or Not
DefaultFont	Font	Get or Set the Default Font
GetFont(_Index As Integer)	Font	Get the Specific Indexed Font from List
FontHeight	Single	Get or Set the Default Font Height
FontSpacing	Single	Get or Set the Default Font Spacing or Padding
DefaultStringFormat	StringFormat	Get or Set the Default StringFormat
GetStringFormat(_Index As Integer)	StringFormat	Get the Specific Indexed StringFormat
SetBrush	Brush	Set the Default Brush
xPos	Single	Get or Set the Current x (horizontal) Position
yPos	Single	Get or Set the Current y (vertical) Position
Page	Integer	Get the Current Page Number

Class Routines:

Routine Name	Parameters	Description
AddFont	System.Drawing.Font	Add a Font to the List
AddStringFormat	System.Drawing.StringFormat	Add a StringFormat to the List
AddBlankLine		Add a Line Height to the Current Y Location

The PrintHelperPages.vb Class:

Option Explicit On
Option Strict On

'  William Dowling       BDowling@TreelessSoftware.com
'  Treeless Software     www.TreelessSoftware.com

Imports System.IO
Imports System.Drawing
Imports System.Drawing.Printing

Public Class PrintHelperPages

#Region " Local Variables "

Private m_FontHeight As Single                      ' Character height of font
    Private m_FontSpacing As Single                     ' Extra spacing/padding between lines
    Private m_xPos As Single                            ' Current x (left margin) position to print at
    Private m_yPos As Single                            ' Current y (line) position to print at
    Private m_Event As PrintPageEventArgs               ' System.Drawing.Printing.
    Private m_Brush As Brush                            ' Default brush
    Private m_Debug As Boolean                          ' debug flag
    Private m_Page As Integer                           ' Current Page Number
    Private m_yCurrent As Single                        ' Current Working Y coordinate for Page
    '******************
    ' Page Layout Stuff
    '******************
    Private m_LayoutMode As Boolean                             ' layout mode
    Private m_fontList As List(Of System.Drawing.Font)          ' Font List - Default is at Index 0
    Private m_sfList As List(Of System.Drawing.StringFormat)    ' StringFormat List - Default is at Index 0

''' <summary>
    ''' Print Helper Page Layout Structure
    ''' </summary>
    ''' <remarks></remarks>
    Structure phLayout
        Public Text As String                           ' Text to Print
        Public fIndex As Integer                        ' Font List Index
        Public sfIndex As Integer                       ' StringFormat List Index
        Public Page As Integer                          ' Page Number of Text
        Public x As Single                              ' X Position to start
        Public y As Single                              ' Y Position to start
        Public AlignToX As Boolean                      ' Alignment is based on X rather than margin width
    End Structure

#End Region

#Region " Public Properties "

''' <summary>
    ''' Get or Set the Debug Flag
    ''' </summary>
    ''' <value>Debug Flag</value>
    ''' <returns>Debug Flag</returns>
    ''' <remarks></remarks>
    Public Property Debug() As Boolean
        Get
            Return m_Debug
        End Get
        Set(value As Boolean)
            m_Debug = value
        End Set
    End Property

''' <summary>
    ''' Get or Set whether we are in Layout Mode or Not
    ''' </summary>
    ''' <value></value>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Property LayoutMode As Boolean
        Get
            Return m_LayoutMode
        End Get
        Set(value As Boolean)
            m_LayoutMode = value
        End Set
    End Property

''' <summary>
    ''' Get or Set the Default Font
    ''' </summary>
    ''' <value>Default Font</value>
    ''' <returns>Default Font</returns>
    ''' <remarks>The Default Font is always at Index 0</remarks>
    Public Property DefaultFont() As Font
        Get
            Return m_fontList(0)
        End Get
        Set(value As Font)
            m_fontList(0) = value
            m_FontHeight = m_Event.Graphics.MeasureString("M", value).Height
        End Set
    End Property

''' <summary>
    ''' Get the Specific Indexed Font from List
    ''' </summary>
    ''' <param name="_Index">Index of Font in Font List</param>
    ''' <value>Specific Indexed Font</value>
    ''' <returns>Specific Indexed Font</returns>
    ''' <remarks></remarks>
    Public ReadOnly Property GetFont(_Index As Integer) As Font
        Get
            Return m_fontList(_Index)
        End Get
    End Property

''' <summary>
    ''' Get or Set the Default Font Height
    ''' </summary>
    ''' <value>Default Font Height</value>
    ''' <returns>Default Font Height</returns>
    ''' <remarks></remarks>
    Public Property FontHeight() As Single
        Get
            Return m_FontHeight
        End Get
        Set(value As Single)
            m_FontHeight = value
        End Set
    End Property

''' <summary>
    ''' Get or Set the Default Font Spacing or Padding
    ''' </summary>
    ''' <value>Default Font Spacing or Padding</value>
    ''' <returns>Default Font Spacing or Padding</returns>
    ''' <remarks></remarks>
    Public Property FontSpacing() As Single
        Get
            Return m_FontSpacing
        End Get
        Set(value As Single)
            m_FontSpacing = value
        End Set
    End Property

''' <summary>
    ''' Get or Set the Default StringFormat
    ''' </summary>
    ''' <value>Default StringFormat</value>
    ''' <returns>Default StringFormat</returns>
    ''' <remarks>The Default StringFormat is always at Index 0</remarks>
    Public Property DefaultStringFormat() As StringFormat
        Get
            Return m_sfList(0)
        End Get
        Set(value As StringFormat)
            m_sfList(0) = value
        End Set
    End Property

''' <summary>
    ''' Get the Specific Indexed StringFormat
    ''' </summary>
    ''' <param name="_Index">Index of StringFormat in StringFormat List</param>
    ''' <value>Specific Indexed StringFormat</value>
    ''' <returns>Specific Indexed StringFormat</returns>
    ''' <remarks></remarks>
    Public ReadOnly Property GetStringFormat(_Index As Integer) As StringFormat
        Get
            Return m_sfList(_Index)
        End Get
    End Property

''' <summary>
    ''' Set the Default Brush
    ''' </summary>
    ''' <value>Default Brush</value>
    ''' <remarks></remarks>
    Public WriteOnly Property SetBrush() As Brush
        Set(value As Brush)
            m_Brush = value
        End Set
    End Property

''' <summary>
    ''' Get or Set the Current x (horizontal) Position
    ''' </summary>
    ''' <value>Current x (horizontal) Position</value>
    ''' <returns>Current x (horizontal) Position</returns>
    ''' <remarks></remarks>
    Public Property xPos() As Single
        Get
            Return m_xPos
        End Get
        Set(value As Single)
            m_xPos = value
        End Set
    End Property

''' <summary>
    ''' Get or Set the Current y (vertical) Position
    ''' </summary>
    ''' <value>Current y (vertical) Position</value>
    ''' <returns>Current y (vertical) Position</returns>
    ''' <remarks></remarks>
    Public Property yPos() As Single
        Get
            Return m_yPos
        End Get
        Set(value As Single)
            m_yPos = value
        End Set
    End Property

''' <summary>
    ''' Get the Current Page Number
    ''' </summary>
    ''' <value>Current Page Number</value>
    ''' <returns>Current Page Number</returns>
    ''' <remarks></remarks>
    Public ReadOnly Property Page() As Integer
        Get
            Return m_Page
        End Get
    End Property

#End Region

''' <summary>
    ''' Create a new instance of the Print Helper Class
    ''' </summary>
    ''' <param name="_event">PrintPageEventArgs</param>
    ''' <param name="_font">Optional Default Font</param>
    ''' <param name="_debug">Optional Debug Flag</param>
    ''' <remarks></remarks>
    Public Sub New(_event As System.Drawing.Printing.PrintPageEventArgs, _
                   Optional _font As Font = Nothing, _
                   Optional _debug As Boolean = False)
        '************************
        ' Create the Layout Lists
        '************************
        m_fontList = New List(Of System.Drawing.Font)
        m_sfList = New List(Of System.Drawing.StringFormat)
        '******************************
        ' Save the Contructor variables
        '******************************
        m_Event = _event
        m_Debug = _debug
        '*************
        ' Default Font
        '*************
        If _font Is Nothing Then
            Me.AddFont(New Font("Arial", 10, FontStyle.Regular))
        Else
            Me.AddFont(_font)                           ' Default font and height
        End If
        m_FontHeight = m_Event.Graphics.MeasureString("M", Me.DefaultFont).Height
        '**********************
        ' Default String Format
        '**********************
        Me.AddStringFormat(New StringFormat)            ' Default String Format
        Me.DefaultStringFormat.Alignment = StringAlignment.Near
        Me.DefaultStringFormat.FormatFlags = StringFormatFlags.LineLimit
        Me.DefaultStringFormat.Trimming = StringTrimming.Word
        '************
        ' Init Values
        '************
        m_xPos = m_Event.MarginBounds.X                 ' starting x position
        m_yPos = m_Event.MarginBounds.Y                 ' starting y position
        m_Page = 1                                      ' start on page one
        m_yCurrent = m_yPos                             ' Start at the beginning
        m_LayoutMode = False                            ' Not in Layout Mode unless told
        m_FontSpacing = 0                               ' Default no line spacing/padding
        m_Brush = Brushes.Black                         ' default brush
        If m_Debug = True Then m_Event.Graphics.DrawRectangle(Pens.Red, m_Event.MarginBounds)
    End Sub

''' <summary>
    ''' Add a Font to the List
    ''' </summary>
    ''' <param name="_Font">Font to Add</param>
    ''' <remarks></remarks>
    Public Sub AddFont(_Font As System.Drawing.Font)
        m_fontList.Add(_Font)
    End Sub

''' <summary>
    ''' Add a StringFormat to the List
    ''' </summary>
    ''' <param name="_StringFormat">StringFormat to Add</param>
    ''' <remarks></remarks>
    Public Sub AddStringFormat(_StringFormat As System.Drawing.StringFormat)
        m_sfList.Add(_StringFormat)
    End Sub

''' <summary>
    ''' Add a Line Height to the Current Y Location
    ''' </summary>
    ''' <remarks></remarks>
    Public Sub AddBlankLine()
        m_yPos += m_FontHeight + m_FontSpacing
    End Sub

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <param name="_HeaderFooter">Are we printing a Header or Footer outside usable range</param>
    ''' <param name="_AlignToX">Alignment is based on X rather than margin width</param>
    ''' <returns>Page Helper Layout Structure</returns>
    ''' <remarks></remarks>
    Public Function Print(_text As String, _
                          Optional _UpdateX As Boolean = False, _
                          Optional _HeaderFooter As Boolean = False, _
                          Optional _AlignToX As Boolean = False) As phLayout
        Return Me.Print(_text, 0, 0, m_xPos, m_yPos, _UpdateX, _HeaderFooter, _AlignToX)
    End Function

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_fontIndex">Font Index to use</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <param name="_HeaderFooter">Are we printing a Header or Footer outside usable range</param>
    ''' <param name="_AlignToX">Alignment is based on X rather than margin width</param>
    ''' <returns>Page Helper Layout Structure</returns>
    ''' <remarks></remarks>
    Public Function Print(_text As String, _
                          _fontIndex As Integer, _
                          Optional _UpdateX As Boolean = False, _
                          Optional _HeaderFooter As Boolean = False, _
                          Optional _AlignToX As Boolean = False) As phLayout
        Return Me.Print(_text, _fontIndex, 0, m_xPos, m_yPos, _UpdateX, _HeaderFooter, _AlignToX)
    End Function

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_x">Starting x Position</param>
    ''' <param name="_y">Starting y Position</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <param name="_HeaderFooter">Are we printing a Header or Footer outside usable range</param>
    ''' <param name="_AlignToX">Alignment is based on X rather than margin width</param>
    ''' <returns>Page Helper Layout Structure</returns>
    ''' <remarks></remarks>
    Public Function Print(_text As String, _
                          _x As Single, _
                          _y As Single, _
                          Optional _UpdateX As Boolean = False, _
                          Optional _HeaderFooter As Boolean = False, _
                          Optional _AlignToX As Boolean = False) As phLayout
        Return Me.Print(_text, 0, 0, _x, _y, _UpdateX, _HeaderFooter, _AlignToX)
    End Function

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_phLayouts">PrintHelper Layout List</param>
    ''' <param name="_Page">Page to Print</param>
    ''' <remarks></remarks>
    Public Sub Print(_phLayouts As List(Of phLayout), _Page As Integer)
        For Each phl As phLayout In _phLayouts
            If phl.Page = _Page Then Me.Print(phl)
        Next
    End Sub

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_phl">Page Helper Layout Structure</param>
    ''' <remarks></remarks>
    Public Sub Print(_phl As phLayout)
        Me.Print(_phl.Text, _phl.fIndex, _phl.sfIndex, _phl.x, _phl.y, False, False, _phl.AlignToX)
    End Sub

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_fontIndex">Font Index to use</param>
    ''' <param name="_sfIndex">StringFormat Index to use</param>
    ''' <param name="_x">Starting x Position</param>
    ''' <param name="_y">Starting y Position</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <param name="_HeaderFooter">Are we printing a Header or Footer outside usable range</param>
    ''' <param name="_AlignToX">Alignment is based on X rather than margin width</param>
    ''' <returns>Page Helper Layout Structure</returns>
    ''' <remarks></remarks>
    Public Function Print(_text As String, _
                          _fontIndex As Integer, _
                          _sfIndex As Integer, _
                          _x As Single, _
                          _y As Single, _
                          Optional _UpdateX As Boolean = False, _
                          Optional _HeaderFooter As Boolean = False, _
                          Optional _AlignToX As Boolean = False) As phLayout
        Dim _font As Font = Me.GetFont(_fontIndex)
        Dim _sf As StringFormat = Me.GetStringFormat(_sfIndex)
        '**************************************************
        ' If text is blank, causes problem with line height
        '**************************************************
        If _text.Length = 0 Then _text = " "
        '***********************************
        ' See if we need to force a new page
        '***********************************
        If _y + m_FontHeight > m_Event.MarginBounds.Bottom AndAlso Not _HeaderFooter Then
            '***********************
            ' First time in Overflow
            '***********************
            If _y <> m_yCurrent Then
                m_yCurrent = _y
                m_Page += 1
                m_yPos = m_Event.MarginBounds.Y         ' force top of page for new page
            End If
            '***************************************
            ' Force Overflow to start at top of page
            '***************************************
            _y = m_Event.MarginBounds.Y
        Else
            '**********************************************************
            ' Not overflowing or forcing printing outsite of boundaries
            '**********************************************************
            m_yCurrent = _y
        End If
        '*************************************************************************
        ' The rectangle we are allowed to use from X, Y position to bottom of page
        '*************************************************************************
        Dim rfRect As RectangleF = New RectangleF(_x, _
                                                  _y, _
                                                  m_Event.MarginBounds.Width - _x + m_Event.MarginBounds.X, _
                                                  m_Event.MarginBounds.Bottom - _y)
        If _sf.Alignment <> StringAlignment.Near Then rfRect.Width += _x - m_Event.MarginBounds.X
        '*********************************************************
        ' The actual size of the rectange needed to print our text
        '*********************************************************
        Dim sfText As SizeF = m_Event.Graphics.MeasureString(_text, _
                                                             _font, _
                                                             CType(rfRect.Width, Integer), _
                                                             _sf)
        If _AlignToX Then
            If _sf.Alignment = StringAlignment.Center Then rfRect.X = _x - (sfText.Width / 2)
            If _sf.Alignment = StringAlignment.Far Then rfRect.X = _x - sfText.Width
            _sf = m_sfList(0)
        End If
        '***************************************
        ' Draw (print) the text in our rectangle
        '***************************************
        If Not Me.LayoutMode Then
            m_Event.Graphics.DrawString(_text.Trim, _
                                        _font, _
                                        m_Brush, _
                                        rfRect, _
                                        _sf)
        End If
        '*************************************************************
        ' Bump up our Y (vertical) position by the height we just used
        '*************************************************************
        m_yPos = _y + sfText.Height + m_FontSpacing
        If _UpdateX Then m_xPos = _x + sfText.Width
        '***********************************************************
        ' If we are in Debug mode, draw a pretty box around the text
        '***********************************************************
        If m_Debug = True AndAlso Not Me.LayoutMode Then
            If _sf.Alignment = StringAlignment.Center Then rfRect.X = rfRect.X + (rfRect.Width / 2) - (sfText.Width / 2)
            If _sf.Alignment = StringAlignment.Far Then rfRect.X = m_Event.MarginBounds.Right - sfText.Width
            m_Event.Graphics.DrawRectangle(Pens.Green, _
                                           rfRect.X, _
                                           rfRect.Y, _
                                           sfText.Width, _
                                           sfText.Height)
        End If
        '*******************************
        ' Create the Print Helper Layout
        '*******************************
        Dim phl As New phLayout
        phl.Text = _text
        phl.fIndex = _fontIndex
        phl.sfIndex = _sfIndex
        phl.Page = m_Page
        phl.x = _x
        phl.y = _y
        phl.AlignToX = _AlignToX
        Return phl
    End Function

End Class

The follow is a demo program to test the PrintHelperPages Class.

Create a new Windows Form Application Project with Visual Studio.
Create a PrintHelperPages Class with the above code.
Create a Button on the default Form1.
Use the follow code for Form1

Option Explicit On
Option Strict On

Imports Microsoft.Win32
Imports System.IO
Imports System.Data.OleDb
Imports System.Drawing.Printing

Public Class Form1

Private m_pd As PrintDocument = Nothing
    Private m_bPreview As Boolean = True
    Private m_fSmall As System.Drawing.Font = Nothing
    Private m_fNormal As System.Drawing.Font = Nothing
    Private m_fNormalB As System.Drawing.Font = Nothing
    Private m_sfCenter As System.Drawing.StringFormat = Nothing
    Private m_sfRight As System.Drawing.StringFormat = Nothing
    Private m_php As PrintHelperPages = Nothing
    Private m_phl As List(Of PrintHelperPages.phLayout)
    Private m_nCurrentPage As Integer = 0
    Private m_nLastPage As Integer = 0
    Private m_EventArgs As System.Drawing.Printing.PrintPageEventArgs = Nothing
    Private m_bPageLayoutHasBeenDone As Boolean = False
    '********************
    ' Font List Positions
    '********************
    Private Enum eFont As Integer
        DefaultPHP = 0
        fSmall = 1
        fNormal = 2
        fNormalB = 3
    End Enum
    '****************************
    ' StringFormat List Positions
    '****************************
    Private Enum eSF As Integer
        DefaultPHP = 0
        sfCenter = 1
        sfRight = 2
    End Enum

''' <summary>
    ''' Form is loading
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub Form1_Load(sender As Object, e As System.EventArgs) Handles Me.Load
        m_pd = New PrintDocument
        m_bPreview = True
    End Sub

''' <summary>
    ''' Click on the button to test the demo
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        AddHandler m_pd.BeginPrint, AddressOf pd_BeginPrint
        AddHandler m_pd.PrintPage, AddressOf pd_PrintPage
        Try
            m_phl = New List(Of PrintHelperPages.phLayout)
            '******************
            ' Set up some Fonts
            '******************
            m_fSmall = New System.Drawing.Font("Arial", 8, FontStyle.Regular)
            m_fNormal = New System.Drawing.Font("Arial", 10, FontStyle.Regular)
            m_fNormalB = New System.Drawing.Font("Arial", 10, FontStyle.Bold)
            '***************************
            ' Set up some string formats
            '***************************
            m_sfCenter = New StringFormat
            m_sfCenter.Alignment = StringAlignment.Center
            m_sfCenter.LineAlignment = StringAlignment.Near
            m_sfRight = New StringFormat
            m_sfRight.Alignment = StringAlignment.Far
            m_sfRight.LineAlignment = StringAlignment.Near
            '*****************************
            ' Print or Preview the page(s)
            '*****************************
            If m_bPreview Then
                Dim ppd As New PrintPreviewDialog
                CType(ppd, Form).WindowState = FormWindowState.Maximized
                ppd.Document = m_pd
                ppd.ShowDialog()
            Else
                Dim pdlg As New PrintDialog
                pdlg.Document = m_pd
                If pdlg.ShowDialog() = DialogResult.OK Then m_pd.Print()
            End If
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        Finally
            RemoveHandler m_pd.PrintPage, AddressOf pd_PrintPage
            RemoveHandler m_pd.BeginPrint, AddressOf pd_BeginPrint
        End Try
    End Sub

''' <summary>
    ''' Occurs when the Print method is called and before the first page of the document prints.
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub pd_BeginPrint(ByVal sender As System.Object, ByVal e As System.Drawing.Printing.PrintEventArgs)
        m_nCurrentPage = 0                              ' Reset page number
    End Sub

''' <summary>
    ''' Occurs when the output to print for the current page is needed.
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub pd_PrintPage(ByVal sender As System.Object, ByVal e As System.Drawing.Printing.PrintPageEventArgs)
        m_php = New PrintHelperPages(e, m_fNormal)
        '******************
        ' Set up some Fonts
        '******************
        m_php.AddFont(m_fSmall)
        m_php.AddFont(m_fNormal)
        m_php.AddFont(m_fNormalB)
        '***************************
        ' Set up some string formats
        '***************************
        m_php.AddStringFormat(m_sfCenter)
        m_php.AddStringFormat(m_sfRight)
        '*********************************
        ' Layout the Pages if not done yet
        '*********************************
        If Not m_bPageLayoutHasBeenDone Then Me.PageLayout(sender, e)
        '*******************
        ' Print out the page
        '*******************
        m_nCurrentPage += 1
        m_php.Print(m_phl, m_nCurrentPage)
        '*******************************************************************************
        ' Print out the Footer at the bottom of the page outside of printable boundaries
        '*******************************************************************************
        Dim nX As Single = e.MarginBounds.Left
        Dim nY As Single = e.MarginBounds.Bottom
        m_php.Print(Date.Now.ToLongDateString, eFont.fSmall, nX, nY, , True)
        m_php.Print(m_nCurrentPage.ToString + " of " + m_nLastPage.ToString, eFont.fSmall, eSF.sfRight, nY, , True)
        '****************************************
        ' See if we have more pages to show/print
        '****************************************
        If m_nCurrentPage < m_nLastPage Then
            e.HasMorePages = True
        Else
            e.HasMorePages = False
        End If
    End Sub

''' <summary>
    ''' Routine to layout the printed pages
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub PageLayout(ByVal sender As System.Object, ByVal e As System.Drawing.Printing.PrintPageEventArgs)
        '****************************
        ' Figure out some coordinates
        '****************************
        Dim nX As Single = e.MarginBounds.Left
        '***********
        ' Page Title
        '***********
        m_php.LayoutMode = True
        m_phl.Add(m_php.Print("Test Demo for PrintHelperPages", eFont.fNormalB, eSF.sfCenter))
        m_php.AddBlankLine()
        '***************
        ' Mult line text
        '***************
        Dim sText As String = "The quick brown fox jumps over the lazy dog. "
        sText += sText + sText + sText + sText + sText + sText
        m_phl.Add(m_php.Print(sText))
        m_php.AddBlankLine()
        '*********************
        ' And here is the data
        '*********************
        Dim nY As Single = m_php.yPos                   ' Current Y on page
        For nIndex As Integer = 1 To 300                ' These will all print on the same line
            If (nIndex Mod 3) = 1 Then
                m_phl.Add(m_php.Print("Left Index " + nIndex.ToString, eFont.fNormal))
            ElseIf (nIndex Mod 3) = 2 Then
                m_phl.Add(m_php.Print("Center Index " + nIndex.ToString, eFont.fNormal, eSF.sfCenter, nY))
            Else
                m_phl.Add(m_php.Print("Right Index " + nIndex.ToString, eFont.fNormal, eSF.sfRight, nY))
                nY = m_php.yPos                         ' Set for next line
            End If
        Next
        '************************************
        ' All done with the layout, flag done
        '************************************
        m_nLastPage = m_php.Page                        ' Get page number of last thing printed
        m_bPageLayoutHasBeenDone = True
        m_php.LayoutMode = False
    End Sub

End Class

Treeless Software

PC and Web Software Development.

Latest News

New VB.Net and SQL Examples

New Website Launched

July 7, 2011

Useful Links

Search