Treeless Software VB example class is used to Print text

This VB class is used to Print text.

Option Explicit On
Option Strict On

Imports System.IO
Imports System.Drawing
Imports System.Drawing.Printing

Public Class PrintHelper

#Region " Local Variables "

Private m_Font As Font                      ' The Font
    Private m_FontHeight As Single              ' Character height of font
    Private m_FontSpacing As Single             ' Extra spacing/padding between lines
    Private m_xPos As Single                    ' Current x (left margin) position to print at
    Private m_yPos As Single                    ' Current y (line) position to print at
    Private m_StringFormat As StringFormat      ' Default string format
    Private m_Event As PrintPageEventArgs       ' System.Drawing.Printing.
    Private m_Brush As Brush                    ' Default brush
    Private m_Debug As Boolean                  ' debug flag

#End Region

#Region " Public Properties "

''' <summary>
    ''' Get or Set the Debug Flag
    ''' </summary>
    ''' <value>Debug Flag</value>
    ''' <returns>Debug Flag</returns>
    ''' <remarks></remarks>
    Public Property Debug() As Boolean
        Get
            Return m_Debug
        End Get
        Set(value As Boolean)
            m_Debug = value
        End Set
    End Property

''' <summary>
    ''' Set the Default Font
    ''' </summary>
    ''' <value>Default Font</value>
    ''' <remarks></remarks>
    Public WriteOnly Property SetFont() As Font
        Set(value As Font)
            m_Font = value
            m_FontHeight = m_Event.Graphics.MeasureString("M", m_Font).Height
        End Set
    End Property

''' <summary>
    ''' Get or Set the Default Font Height
    ''' </summary>
    ''' <value>Default Font Height</value>
    ''' <returns>Default Font Height</returns>
    ''' <remarks></remarks>
    Public Property FontHeight() As Single
        Get
            Return m_FontHeight
        End Get
        Set(value As Single)
            m_FontHeight = value
        End Set
    End Property

''' <summary>
    ''' Get or Set the Default Font Spacing or Padding
    ''' </summary>
    ''' <value>Default Font Spacing or Padding</value>
    ''' <returns>Default Font Spacing or Padding</returns>
    ''' <remarks></remarks>
    Public Property FontSpacing() As Single
        Get
            Return m_FontSpacing
        End Get
        Set(value As Single)
            m_FontSpacing = value
        End Set
    End Property

''' <summary>
    ''' Set the Default String Format
    ''' </summary>
    ''' <value>Default String Format</value>
    ''' <remarks></remarks>
    Public WriteOnly Property SetStringFormat() As StringFormat
        Set(value As StringFormat)
            m_StringFormat = value
        End Set
    End Property

''' <summary>
    ''' Set the Default Brush
    ''' </summary>
    ''' <value>Default Brush</value>
    ''' <remarks></remarks>
    Public WriteOnly Property SetBrush() As Brush
        Set(value As Brush)
            m_Brush = value
        End Set
    End Property

''' <summary>
    ''' Get or Set the Current x (horizontal) Position
    ''' </summary>
    ''' <value>Current x (horizontal) Position</value>
    ''' <returns>Current x (horizontal) Position</returns>
    ''' <remarks></remarks>
    Public Property xPos() As Single
        Get
            Return m_xPos
        End Get
        Set(value As Single)
            m_xPos = value
        End Set
    End Property

''' <summary>
    ''' Get or Set the Current y (vertical) Position
    ''' </summary>
    ''' <value>Current y (vertical) Position</value>
    ''' <returns>Current y (vertical) Position</returns>
    ''' <remarks></remarks>
    Public Property yPos() As Single
        Get
            Return m_yPos
        End Get
        Set(value As Single)
            m_yPos = value
        End Set
    End Property

#End Region

''' <summary>
    ''' Create a new instance of the Print Helper Class
    ''' </summary>
    ''' <param name="_event">PrintPageEventArgs</param>
    ''' <param name="_font">Optional Default Font</param>
    ''' <param name="_debug">Optional Debug Flag</param>
    ''' <remarks></remarks>
    Public Sub New(ByVal _event As System.Drawing.Printing.PrintPageEventArgs, _
                   Optional ByVal _font As Font = Nothing, _
                   Optional ByVal _debug As Boolean = False)
        m_Event = _event
        m_Debug = _debug
        If _font Is Nothing Then
            SetFont = New Font("Arial", 10, FontStyle.Regular)
        Else
            SetFont = _font                             ' Default font and height
        End If
        m_FontSpacing = 0                               ' Default no line spacing/padding
        m_StringFormat = New StringFormat               ' Default String Format
        m_StringFormat.Alignment = StringAlignment.Near
        m_StringFormat.FormatFlags = StringFormatFlags.LineLimit
        m_StringFormat.Trimming = StringTrimming.Word
        m_xPos = m_Event.MarginBounds.X                 ' starting x position
        m_yPos = m_Event.MarginBounds.Y                 ' starting y position
        m_Brush = Brushes.Black                         ' default brush
        If m_Debug = True Then m_Event.Graphics.DrawRectangle(Pens.Red, m_Event.MarginBounds)
    End Sub

''' <summary>
    ''' Add a Line Height to the Current Y Location
    ''' </summary>
    ''' <remarks></remarks>
    Public Sub AddBlankLine()
        m_yPos += m_FontHeight + m_FontSpacing
    End Sub

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <remarks></remarks>
    Public Sub Print(ByVal _text As String, _
                     Optional ByVal _UpdateX As Boolean = False)
        Print(_text, m_Font, m_StringFormat, m_xPos, m_yPos, _UpdateX)
    End Sub

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_font">Font to use</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <remarks></remarks>
    Public Sub Print(ByVal _text As String, _
                     ByVal _font As Font, _
                     Optional ByVal _UpdateX As Boolean = False)
        Print(_text, _font, m_StringFormat, m_xPos, m_yPos, _UpdateX)
    End Sub

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_font">Font to use</param>
    ''' <param name="_sf">String Format to use</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <remarks></remarks>
    Public Sub Print(ByVal _text As String, _
                     ByVal _font As Font, _
                     ByVal _sf As StringFormat, _
                     Optional ByVal _UpdateX As Boolean = False)
        Print(_text, _font, _sf, m_Event.MarginBounds.X, m_yPos, _UpdateX)
    End Sub

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_font">Font to use</param>
    ''' <param name="x">Starting x Position</param>
    ''' <param name="y">Starting y Position</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <remarks></remarks>
    Public Sub Print(ByVal _text As String, _
                     ByVal _font As Font, _
                     ByVal x As Single, _
                     ByVal y As Single, _
                     Optional ByVal _UpdateX As Boolean = False)
        Print(_text, _font, m_StringFormat, x, y, _UpdateX)
    End Sub

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="x">Starting x Position</param>
    ''' <param name="y">Starting y Position</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <remarks></remarks>
    Public Sub Print(ByVal _text As String, _
                     ByVal x As Single, _
                     ByVal y As Single, _
                     Optional ByVal _UpdateX As Boolean = False)
        Print(_text, m_Font, m_StringFormat, x, y, _UpdateX)
    End Sub

''' <summary>
    ''' Print Text to the Printer
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_font">Font to use</param>
    ''' <param name="_sf">String Format to use</param>
    ''' <param name="x">Starting x Position</param>
    ''' <param name="y">Starting y Position</param>
    ''' <param name="_UpdateX">Update the X position after Printing</param>
    ''' <remarks></remarks>
    Public Sub Print(ByVal _text As String, _
                     ByVal _font As Font, _
                     ByVal _sf As StringFormat, _
                     ByVal x As Single, _
                     ByVal y As Single, _
                     Optional ByVal _UpdateX As Boolean = False)
        '**************************************************
        ' If text is blank, causes problem with line height
        '**************************************************
        If _text.Length = 0 Then _text = " "
        '*************************************************************************
        ' The rectangle we are allowed to use from X, Y position to bottom of page
        '*************************************************************************
        Dim rfRect As RectangleF = New RectangleF(x, _
                                                  y, _
                                                  m_Event.MarginBounds.Width - x + m_Event.MarginBounds.X, _
                                                  m_Event.MarginBounds.Bottom - y)
        If _sf.Alignment <> StringAlignment.Near Then rfRect.Width += x - m_Event.MarginBounds.X
        '***************************************
        ' Draw (print) the text in our rectangle
        '***************************************
        m_Event.Graphics.DrawString(_text.Trim, _
                                    _font, _
                                    m_Brush, _
                                    rfRect, _
                                    _sf)
        '*********************************************************
        ' The actual size of the rectange needed to print our text
        '*********************************************************
        Dim sfText As SizeF = m_Event.Graphics.MeasureString(_text, _
                                                             _font, _
                                                             CType(rfRect.Width, Integer), _
                                                             _sf)
        '*************************************************************
        ' Bump up our Y (vertical) position by the height we just used
        '*************************************************************
        m_yPos = y + sfText.Height + m_FontSpacing
        If _UpdateX Then m_xPos = x + sfText.Width
        '***********************************************************
        ' If we are in Debug mode, draw a pretty box around the text
        '***********************************************************
        If m_Debug = True Then
            If _sf.Alignment = StringAlignment.Center Then rfRect.X = rfRect.X + (rfRect.Width / 2) - (sfText.Width / 2)
            m_Event.Graphics.DrawRectangle(Pens.Green, _
                                           rfRect.X, _
                                           rfRect.Y, _
                                           sfText.Width, _
                                           sfText.Height)
        End If
    End Sub

''' <summary>
    ''' Print Text to the Printer and Draw a box around it
    ''' </summary>
    ''' <param name="_text">Text to Print</param>
    ''' <param name="_font">Font to use</param>
    ''' <param name="x">Starting x Position</param>
    ''' <param name="y">Starting y Position</param>
    ''' <param name="_width">Width of Box</param>
    ''' <param name="_height">Height of Box</param>
    ''' <remarks></remarks>
    Public Sub PrintBox(ByVal _text As String, _
                        ByVal _font As Font, _
                        ByVal x As Single, _
                        ByVal y As Single, _
                        ByVal _width As Single, _
                        ByVal _height As Single)
        '*****************************************************************************
        ' The rectangle we are allowed to use from X, Y position with width and height
        '*****************************************************************************
        Dim rfRect As RectangleF = New RectangleF(x, _
                                                  y, _
                                                  _width, _
                                                  _height)
        '***************************************
        ' Draw (print) the text in our rectangle
        '***************************************
        m_Event.Graphics.DrawString(_text, _
                                    _font, _
                                    m_Brush, _
                                    rfRect, _
                                    m_StringFormat)
        '*********************************************************
        ' The actual size of the rectange needed to print our text
        '*********************************************************
        Dim sfText As SizeF = m_Event.Graphics.MeasureString(_text, _
                                                             _font, _
                                                             CType(rfRect.Width, Integer), _
                                                             m_StringFormat)
        '*************************************************************
        ' Bump up our Y (vertical) position by the height we just used
        '*************************************************************
        m_yPos = y + sfText.Height + m_FontSpacing
        '***************************************************
        ' And draw a pretty box around our defined rectangle
        '***************************************************
        If m_StringFormat.Alignment = StringAlignment.Center Then rfRect.X = rfRect.X + (rfRect.Width / 2) - (sfText.Width / 2)
        m_Event.Graphics.DrawRectangle(Pens.Black, _
                                       rfRect.X, _
                                       rfRect.Y, _
                                       rfRect.Width, _
                                       rfRect.Height)
    End Sub

''' <summary>
    ''' Print an Underline
    ''' </summary>
    ''' <param name="_font">Font to Size bottom of line</param>
    ''' <param name="x">Starting x Position</param>
    ''' <param name="y">Starting y Position</param>
    ''' <param name="_width">Width of Line</param>
    ''' <remarks></remarks>
    Public Sub PrintLine(ByVal _font As Font, _
                         ByVal x As Single, _
                         ByVal y As Single, _
                         ByVal _width As Single)
        m_Event.Graphics.DrawLine(Pens.Black, _
                                  x, _
                                  y + _font.Height, _
                                  x + _width, _
                                  y + _font.Height)
    End Sub

End Class

Treeless Software

PC and Web Software Development.

Latest News

New VB.Net and SQL Examples

New Website Launched

July 7, 2011

Useful Links

Search