Treeless Software VB class to handle Software Registry Key Access

This VB class, myRegistry, is used to process all Registry Key access (GetValue, SetValue) and was written for Visual Studio 2010.

Example of usage;

myRegistry.SetRegistryKey("YourName", "YourProgramName", False)
Dim sDbName As String = myRegistry.GetValue("dbName", "db.mdb", False).ToString
myRegistry.Close()
myRegistry.SetValue("dbName", "Newdb.mdb", True)

Option Explicit On
Option Strict On

Imports Microsoft.Win32
Imports System.IO

''' <summary>
''' Registry Key Routines.
''' </summary>
''' <remarks></remarks>
Public Class myRegistry

#Region " Local Variables "

'****************
    ' Local Constants
    '****************
    Private Const c_Software As String = "Software"
    Private Const c_KeyNotSet As String = "Registry Key Not Set"
    '****************
    ' Local Variables
    '****************
    Private Shared m_regMe As RegistryKey = Nothing

#End Region

#Region " Global Properties "

Public Shared Property RegistryKey As String

#End Region

#Region " Global Procedures "

''' <summary>
    ''' Create the Registry Key for this Application in CurrentUser Software.
    ''' </summary>
    ''' <param name="_CompanyName">Your Company Name</param>
    ''' <param name="_ProgramName">Your Program Name</param>
    ''' <param name="_CloseAfter">Close the Registry Key when Completed.</param>
    ''' <remarks></remarks>
    Public Shared Sub SetRegistryKey(_CompanyName As String, _
                                     _ProgramName As String, _
                                     _CloseAfter As Boolean)
        Dim regSoft As RegistryKey = Registry.CurrentUser.OpenSubKey(c_Software, True)
        RegistryKey = _CompanyName + "\" + _ProgramName
        m_regMe = regSoft.CreateSubKey(RegistryKey)
        RegistryKey = c_Software + "\" + RegistryKey
        regSoft.Close()
        If _CloseAfter Then myRegistry.Close()
    End Sub

''' <summary>
    ''' Retrieves the value associated with the specified name. 
    ''' </summary>
    ''' <param name="_Name">The name of the value to retrieve.</param>
    ''' <param name="_CloseAfter">Close the Registry Key when Completed.</param>
    ''' <returns>The value associated with name, or Nothing if name is not found.</returns>
    ''' <remarks></remarks>
    Public Shared Function GetValue(_Name As String, _
                                    _CloseAfter As Boolean) As Object
        If RegistryKey Is Nothing OrElse RegistryKey.Length = 0 Then Throw New Exception(c_KeyNotSet)
        If m_regMe Is Nothing Then m_regMe = Registry.CurrentUser.CreateSubKey(RegistryKey)
        Dim oValue As Object = m_regMe.GetValue(_Name)
        If _CloseAfter Then myRegistry.Close()
        Return oValue
    End Function

''' <summary>
    ''' Retrieves the value associated with the specified name. 
    ''' If the name is not found, returns the default value that you provide.
    ''' </summary>
    ''' <param name="_Name">The name of the value to retrieve.</param>
    ''' <param name="_DefaultValue">The value to return if name does not exist.</param>
    ''' <param name="_CloseAfter">Close the Registry Key when Completed.</param>
    ''' <returns>The value associated with name, with any embedded environment variables left unexpanded, or defaultValue if name is not found.</returns>
    ''' <remarks></remarks>
    Public Shared Function GetValue(_Name As String, _
                                    _DefaultValue As Object, _
                                    _CloseAfter As Boolean) As Object
        If RegistryKey Is Nothing OrElse RegistryKey.Length = 0 Then Throw New Exception(c_KeyNotSet)
        If m_regMe Is Nothing Then m_regMe = Registry.CurrentUser.CreateSubKey(RegistryKey)
        Dim oValue As Object = m_regMe.GetValue(_Name, _DefaultValue)
        If _CloseAfter Then myRegistry.Close()
        Return oValue
    End Function

''' <summary>
    ''' Sets the specified name/value pair.
    ''' </summary>
    ''' <param name="_Name">The name of the value to store.</param>
    ''' <param name="_Value">The data to be stored.</param>
    ''' <param name="_CloseAfter">Close the Registry Key when Completed.</param>
    ''' <remarks></remarks>
    Public Shared Sub SetValue(_Name As String, _
                               _Value As Object, _
                               _CloseAfter As Boolean)
        If RegistryKey Is Nothing OrElse RegistryKey.Length = 0 Then Throw New Exception(c_KeyNotSet)
        If m_regMe Is Nothing Then m_regMe = Registry.CurrentUser.CreateSubKey(RegistryKey)
        m_regMe.SetValue(_Name, _Value)
        If _CloseAfter Then myRegistry.Close()
    End Sub

''' <summary>
    ''' Sets the value of a name/value pair in the registry key, using the specified registry data type.
    ''' </summary>
    ''' <param name="_Name">The name of the value to store.</param>
    ''' <param name="_Value">The data to be stored.</param>
    ''' <param name="_ValueKind">The registry data type to use when storing the data.</param>
    ''' <param name="_CloseAfter">Close the Registry Key when Completed.</param>
    ''' <remarks></remarks>
    Public Shared Sub SetValue(_Name As String, _
                               _Value As Object, _
                               _ValueKind As RegistryValueKind, _
                               _CloseAfter As Boolean)
        If RegistryKey Is Nothing OrElse RegistryKey.Length = 0 Then Throw New Exception(c_KeyNotSet)
        If m_regMe Is Nothing Then m_regMe = Registry.CurrentUser.CreateSubKey(RegistryKey)
        m_regMe.SetValue(_Name, _Value, _ValueKind)
        If _CloseAfter Then myRegistry.Close()
    End Sub

''' <summary>
    ''' Close the Registry Key
    ''' </summary>
    ''' <remarks></remarks>
    Public Shared Sub Close()
        '***********************
        ' All done with registry
        '***********************
        If m_regMe IsNot Nothing Then m_regMe.Close()
        m_regMe = Nothing
    End Sub

#End Region

End Class

Treeless Software

PC and Web Software Development.

Latest News

New VB.Net and SQL Examples

New Website Launched

July 7, 2011

Useful Links

Search